Connected: An Internet Encyclopedia
5.1. SYNTAX

Up: Connected: An Internet Encyclopedia
Up: RFC 822
Up: 5. DATE AND TIME SPECIFICATION
Prev: 5. DATE AND TIME SPECIFICATION
Next: 5.2. SEMANTICS

5.1. SYNTAX

5.1. SYNTAX

```     date-time   =  [ day "," ] date time        ; dd mm yy
;  hh:mm:ss zzz

day         =  "Mon"  / "Tue" /  "Wed"  / "Thu"
/  "Fri"  / "Sat" /  "Sun"

date        =  1*2DIGIT month 2DIGIT        ; day month year
;  e.g. 20 Jun 82

month       =  "Jan"  /  "Feb" /  "Mar"  /  "Apr"
/  "May"  /  "Jun" /  "Jul"  /  "Aug"
/  "Sep"  /  "Oct" /  "Nov"  /  "Dec"

time        =  hour zone                    ; ANSI and Military

hour        =  2DIGIT ":" 2DIGIT [":" 2DIGIT]
; 00:00:00 - 23:59:59

zone        =  "UT"  / "GMT"                ; Universal Time
; North American : UT
/  "EST" / "EDT"                ;  Eastern:  - 5/ - 4
/  "CST" / "CDT"                ;  Central:  - 6/ - 5
/  "MST" / "MDT"                ;  Mountain: - 7/ - 6
/  "PST" / "PDT"                ;  Pacific:  - 8/ - 7
/  1ALPHA                       ; Military: Z = UT;
;  A:-1; (J not used)
;  M:-12; N:+1; Y:+12
/ ( ("+" / "-") 4DIGIT )        ; Local differential
;  hours+min. (HHMM)
```

Next: 5.2. SEMANTICS

Connected: An Internet Encyclopedia
5.1. SYNTAX